第一十零章 ANSYS参数化设计语言

10.3.2 ANSYS参数化设计实例解析——简支梁的受力分析

    1.问题描述

    图10-4所示为移动载荷作用下的简支梁，确定在活载荷作用下的最不利位置。

    图10-4 移动载荷作用下的简支梁图

    简支梁材料参数如下：

    弹性模量EX=2.06E11，泊松比PRXY=0.3。梁的面积Area=6m²，惯性面积矩IZZ=4.5m²，高Hight=3m。

    2.求解步骤

    建立的有限元模型及服役环境如图10-5所示。共128个单元，129个节点。

    图10-5 有限元模型及服役环境

    3.结果分析

    图10-6、图10-7和图10-8分别显示了简支梁的变形和内力云图。可见，此简支梁在移动载荷和均布载荷作用下的最大位移为21.99mm，最大弯矩为47700kN•m，最大剪力值为2850kN。

    图10-6 最不利载荷位置对应的变形云图

    图10-7 弯矩图

    图10-9显示了简支梁UY的时间历程曲线。从图10-9中容易看出，在56步时，位移达到最大值，因此，上述移动载荷和均布载荷作用下的最不利位置发生在距简支梁右端（64-56）×0.5=4m处。

    图10-8 剪力图

    图10-9 简支梁UY的时间历程曲线

    求解过程利用APDL来实现，其命令流如下：

    /FILNAME, SIMPLE BEAM     ！定义工作文件名

    /TITLE,SEEKING FOR MOST

    DANGEROUS LOADING LOCATION    ！定义工作标题

    /PREP7        ！进入前处理器

    ET,1,BEAM3         ！定义单元类型

    R,1,6,4.5,3        ！定义单元实常数

    MP,EX,1,2.06E11       ！定义材料弹性模量

    MP,PRXY,1,0.3       ！定义材料泊松比

    K,1,0,0,0          ！创建关键点

    K,2,64,0,0 

    LSTR,1,2        ！创建直线段

    LESIZE,ALL,0.5       ！设置单元大小

    LMESH,1         ！对线段划分网格

    FINISH   

    /SOL        ！进入求解器

    D,1,,,,,,UX,UY       ！施加位移约束

    D,2,,,,,,UY  

    ANTYPE,4        ！设置分析类型

    TRNOPT,FULL 

    *SET,TIM,0         ！设置常变量

    *SET,DELT,1 

    *SET,LOAD,200000 

    *SET,ULOAD,92000

    TIMINT,ON 

    *DO,I,0,64,1       ！采用DO循环设置移动载荷

    *SET,TIM,TIM+1 

    TIME,TIM

    NSEL,ALL

    FDELE,ALL,ALL

    NSEL,ALL

    NSEL,S,LOC,X,(64+I)*0.5

    F,ALL,FY,-LOAD 

    NSEL,ALL

    NSEL,S,LOC,X,(64+I-3)*0.5  

    F,ALL,FY,-LOAD

    NSEL,ALL

    NSEL,S,LOC,X,(64+I-6)*0.5

    F,ALL,FY,-LOAD

    NSEL,ALL

    NSEL,S,LOC,X,(64+I-9)*0.5 

    F,ALL,FY,-LOAD 

    NSEL,ALL

    NSEL,S,LOC,X,(64+I-12)*0.5

    F,ALL,FY,-LOAD 

    NSEL,ALL

    NSEL,S,NODE,,66+I-15,1,-1

    F,ALL,FY,-ULOAD/2        ！施加均布载荷

    NSEL,ALL

    NSUBST,1

    OUTRES,ALL,ALL

    SOLVE 

    *ENDDO

    FINISH 

    /POST1 

    /ESHAPE,1      ！设置梁的显示方案

    /DSCALE,1,100      ！设置变形比例

    SET,56       ！读入载荷步

    PLDISP,1       ！显示梁的变形图

    AVPRIN,0,,      ！创建单元表

    ETABLE,,SMISC,2 

    AVPRIN,0,,

    ETABLE,,SMISC,8 

    AVPRIN,0,,

    ETABLE,,SMISC,6 

    AVPRIN,0,,

    ETABLE,,SMISC,12

    PLLS,SMIS6,SMIS12,-1,0     ！画弯矩图

    PLLS,SMIS2,SMIS8,1,0     ！画剪力图

    /POST26       ！进入时间历程后处理器

    /AXLAB,X,TIME(S)     ！设置时间历程图的坐标标识

    /AXLAB,Y,DISPLACEMENT Y(MM) 

    NSOL,2,I,U,Y,NODE10     ！每隔20个节点采集一次Y方向的位移

    NSOL,3,30,U,Y,NODE 30

    NSOL,4,50,U,Y,NODE 50

    NSOL,5,70,U,Y,NODE 70

    NSOL,6,90,U,Y,NODE 90

    NSOL,7,110,U,Y,NODE 110 

    NSOL,8,120,U,Y,NODE 120 

    NSOL,9,129,U,Y,NODE 129 

    PLVAR,2,3,4,5,6,7,8,9     ！显示采集各节点的UY位移历程曲线

    FINISH

    /EXIT,NOSAV      ！退出ANSYS