第五章 复合材料分析

    4.命令流文件

    /FILNAME,EXERCISE    ！定义工作文件名

    /TITLE,BENDING OF A COMPOSITE BEAM ！定义工作标题

    /PREP7      ！进入前处理器

    ET,1,SHELL99     ！定义单元类型

    KEYOPT,1,8,1     ！设置单元关键字

    R,1,3      ！定义单元实常数

    RMORE 

    RMORE,1,0,4,2,0,3.5

    RMORE,3,0,2 

    MP,EX,1,1.2E5      ！定义材料1弹性模量

    MP,PRXY,1,0.32     ！定义材料1泊松比

    MP,ALPX,1,1.8E-6   ！定义材料1热膨胀系数

    MP,ALPY,1,2E-7 

    MP,EX,2,0.4E5 

    MP,PRXY,2,0.26 

    MP,ALPX,2,0.6E-6 

    MP,ALPY,2,0.1E-6

    MP,EX,3,0.8E5 

    MP,PRXY,3,0.28 

    MP,ALPX,3,0.6E-6  

    MP,ALPY,3,0.1E-6  

    RECTNG,0,200,0,10   ！创建矩形面

    LSEL,S,,,1,3,2    ！选择线段1和3

    LESIZE,ALL,,,20    ！设置线段等分数

    LSEL,S,,,2,4,2 

    LESIZE,ALL,,,2 

    ALLSEL     ！选择所有实体

    AMESH,1     ！对面进行网格划分

    LSEL,S,,,2     ！选择线段2

    NSLL,S,1     ！选择线段上的所有节点

    CP,1,ROTY,ALL    ！耦合节点转动位移

    ALLSEL 

    EPLOT     ！显示单元

    LAYPLOT,1,1,3,     ！图形显示层叠信息

    LAYLIST,1,1,3,EX,ALPX   ！列表显示层叠信息

    SAVE,'EXERCISE1','db','E:\ANSYS\' ！保存有限元模型文件

    /SOL     ！进入求解器

    ANTYPE,0     ！指定分析类型

    LSEL,S,,,4 

    NSLL,S,1 

    D,ALL,ALL    ！对节点施加位移约束

    ALLSEL 

    NSEL,S,LOC,X,200   ！选择指定节点

    NSEL,R,LOC,Y,5     ！二次选择节点

    *GET,NC,NODE,,NUM,MIN  ！获取节点编号

    F,NC,MY,1E4      ！施加集中力偶矩载荷

    ALLSEL 

    TUNIF,100,    ！施加均匀温度载荷

    SOLVE        ！开始求解计算

    SAVE,'EXERCISE2','db','E:\ANSYS\' ！保存计算结果

    /POST1        ！进入POST1后处理器

    RSYS,0       ！在直角坐标系中显示结果

    AVPRIN,0,0 

    SHELL,MID       ！使用层的中面

    AVRES,2 

    LAYER,2    ！读取第2层求解结果

    FORCE,TOTAL 

    SET,LAST   ！读取最终求解结果

    PLNSOL,U,X  ！绘制X方向位移场等值线图

    PLNSOL,U,Y 

    PLNSOL,U,Z 

    PLNSOL,U,SUM  ！绘制合位移场等值线图

    PLNSOL,ROT,X  ！绘制沿X轴转动位移场等值线图

    PLNSOL,ROT,Y 

    PLNSOL,ROT,SUM ！绘制总转动位移场等值线图

    PLNSOL,S,X  ！绘制X方向应力场等值线图

    PLNSOL,S,Y 

    PLNSOL,S,EQV  ！绘制等效应力场等值线图

    NSEL,S,LOC,X,200 

    PRNSOL,U,COMP  ！列表显示节点位移求解结果

    PRNSOL,S,PRIN  ！列表显示节点应力求解结果

    ALLSEL 

    PRRSOL   ！列表显示支反力求解结果

    /EXIT,NOSAV     ！退出ANSYS